Move justfile to repository root (#7652)

## Summary
- move the workspace justfile to the repository root for easier
discovery
- set the just working directory to codex-rs so existing recipes still
run in the Rust workspace

## Testing
- not run (not requested)


------
[Codex
Task](https://chatgpt.com/codex/tasks/task_i_69334db473108329b0cc253b7fd8218e)

justfile

@@ -0,0 +1,53 @@
+set working-directory := "codex-rs"
+set positional-arguments
+
+# Display help
+help:
+    just -l
+
+# `codex`
+alias c := codex
+codex *args:
+    cargo run --bin codex -- "$@"
+
+# `codex exec`
+exec *args:
+    cargo run --bin codex -- exec "$@"
+
+# `codex tui`
+tui *args:
+    cargo run --bin codex -- tui "$@"
+
+# Run the CLI version of the file-search crate.
+file-search *args:
+    cargo run --bin codex-file-search -- "$@"
+
+# Build the CLI and run the app-server test client
+app-server-test-client *args:
+    cargo build -p codex-cli
+    cargo run -p codex-app-server-test-client -- --codex-bin ./target/debug/codex "$@"
+
+# format code
+fmt:
+    cargo fmt -- --config imports_granularity=Item
+
+fix *args:
+    cargo clippy --fix --all-features --tests --allow-dirty "$@"
+
+clippy:
+    cargo clippy --all-features --tests "$@"
+
+install:
+    rustup show active-toolchain
+    cargo fetch
+
+# Run `cargo nextest` since it's faster than `cargo test`, though including
+# --no-fail-fast is important to ensure all tests are run.
+#
+# Run `cargo install cargo-nextest` if you don't have it installed.
+test:
+    cargo nextest run --no-fail-fast
+
+# Run the MCP server
+mcp-server-run *args:
+    cargo run -p codex-mcp-server -- "$@"